$!************************************************************************
$!*                                                                      *    
$!*  Copyright Digital Equipment Corporation 1998. All rights reserved.  *
$!*                                                                      *    
$!*  Restricted Rights: Use, duplication, or disclosure by the U.S.      *    
$!*  Government is subject to restrictions as set forth in subparagraph  *    
$!*  (c) (1) (ii) of DFARS 252.227-7013, or in FAR 52.227-19, or in FAR  *    
$!*  52.227-14 Alt. III, as applicable.                                  *    
$!*                                                                      *    
$!*  This software is proprietary to and embodies the confidential       *    
$!*  technology of Digital Equipment Corporation. Possession, use, or    *    
$!*  copying of this software and media is authorized only pursuant to a *    
$!*  valid written license from Digital or an authorized sublicensor.    *    
$!*                                                                      *    
$!************************************************************************
$!
$ ! CRTL_DROP_EXAMPLES_TLB.COM
$ !
$ !   P1  Numaric Version of the drop area (e.g. 60, 61, 62) depending on the
$ !       compiler_version.
$ Say := Write SYS$OUTPUT
$ caller_verify = 'f$verify(0)
$!
$ cc_version = ""
$ if p1 .eqs. "52" then cc_version = "V" + p1
$ if p1 .eqs. "53" then cc_version = "V" + p1
$ if p1 .eqs. "54" then cc_version = "V" + p1
$ if p1 .eqs. "55" then cc_version = "V" + p1
$ if p1 .eqs. "56" then cc_version = "V" + p1
$ if p1 .eqs. "57" then cc_version = "V" + p1
$ if p1 .eqs. "60" then cc_version = "V" + p1
$ if p1 .eqs. "61" then cc_version = "V" + p1
$ if cc_version .eqs. ""
$ then
$    say "wrong CC version"
$    say "specify one of the: 52, 53, 54, 55, 56, 57 or 60 or 61"
$    unused = f$verify(caller_verify)
$    exit 1
$ endif
$!
$ inquire/punctuation dis -
      "have you copied recent C$:[C.MAIL]BUILDERS_AND_TESTERS.DIS here [Y/N]?"
$ if f$extract(0,1,f$edit(dis,"UPCASE")) .nes. "Y"
$ then
$    unused = f$verify(caller_verify)
$    exit 1
$ endif
$ if f$search("BUILDERS_AND_TESTERS.DIS;") .eqs. ""
$ then
$    say "cannot find BUILDERS_AND_TESTERS.DIS in the default directory"
$    unused = f$verify(caller_verify)
$    exit 1
$ endif
$!
$! *** DECC$RTLDEF.TLB ***
$!
$ define/user cms$lib ccmslibs:[headers.crtl]
$ cms fetch/out=crtl_class.txt/nolog 'cc_version'.classname ""
$ open/error=open_err classname crtl_class.txt
$ read/error=read_err classname crtl_class
$ close classname
$!
$ define/user cms$lib ccmslibs:[headers.crtl]
$ cms show class 'crtl_class'
$ if f$search("strcpy_usr$:[crtl.crtl_drop.tmp]*.*;*") .nes. "" then delete/nolog/noconf strcpy_usr$:[crtl.crtl_drop.tmp]*.*;*
$ define/user cms$lib ccmslibs:[headers.crtl]
$ cms fetch *.*/gen='crtl_class'/nolog/out=strcpy_usr$:[crtl.crtl_drop.tmp] ""
$!
$ set prot=(S:RWED,O:RWED,G:RWED,W:RE) strcpy_usr$:[crtl.crtl_drop.tmp]*.*;*
$ library/create/text strcpy_usr$:[crtl.crtl_drop]decc$rtldef_'cc_version'.tlb
$ library/insert/text strcpy_usr$:[crtl.crtl_drop]decc$rtldef_'cc_version'.tlb crtl_class.txt,strcpy_usr$:[crtl.crtl_drop.tmp]*.*
$ delete/nolog/noconf strcpy_usr$:[crtl.crtl_drop.tmp]*.*;*
$!
$ Copy/log/prot=(S:RWED,O:RWED,G:RE,W:RE) -
	strcpy_usr$:[crtl.crtl_drop]decc$rtldef_'cc_version'.tlb -
	tle::crtl$:[public.decc_'cc_version'_rtl]decc$rtldef.tlb
$ If $status
$ then
$	say "DECC$RTLDEF.TLB was successfully copied to the target area"
$ else
$	say "error copying DECC$RTLDEF.TLB to the target area"
$	say "quitting..."
$	goto quit
$ endif
$!
$ index_file = "tle::crtl$:[public.decc_''cc_version'_rtl]decc$rtldef_index.txt"
$ if f$search(index_file) .eqs. "" then create 'index_file'
$ open/append/error=open_index_err decc$rtldef_index 'index_file'
$ notification = "DECC$RTLDEF.TLB for DEC C ''cc_version' created on ''f$time()' using ''crtl_class' CMS class"
$ write/error=write_index_err decc$rtldef_index notification
$ close decc$rtldef_index
$!
$ mail_notification = "new DECC$RTLDEF.TLB for DEC C ''cc_version' based on ''crtl_class' CMS class "
$ mail_notification = mail_notification + "was placed on tle::crtl$:[public.decc_''cc_version'_rtl]"
$ mail/self/sub="''mail_notification'" _nl0: "@BUILDERS_AND_TESTERS.DIS"
$ goto quit
$!
$open_index_err:
$ say "cannot open decc$rtldef_index"
$ delete/nolog/noconf tle::crtl$:[public.decc_'cc_version'_rtl]decc$rtldef.tlb;0
$ goto quit
$!
$write_index_err:
$ say "cannot write decc$rtldef_index"
$ delete/nolog/noconf tle::crtl$:[public.decc_'cc_version'_rtl]decc$rtldef.tlb;0
$ close decc$rtldef_index
$ goto quit
$!
$open_err:
$ say "cannot open crtl_class.txt file"
$ goto quit
$!
$read_err:
$ say "cannot read crtl_class.txt file"
$ close classname
$ goto quit
$!
$quit:
$ delete/nolog/noconf crtl_class.txt;*
$ unused = f$verify(caller_verify)
$ exit 1