%(
	****************************************************************

		Copyright (c) 1992, Carnegie Mellon University

		All Rights Reserved

	Permission  is  hereby  granted   to  use,  copy,  modify,  and
	distribute  this software  provided  that the  above  copyright
	notice appears in  all copies and that  any distribution be for
	noncommercial purposes.

	Carnegie Mellon University disclaims all warranties with regard
	to this software.  In no event shall Carnegie Mellon University
	be liable for  any special, indirect,  or consequential damages
	or any damages whatsoever  resulting from loss of use, data, or
	profits  arising  out of  or in  connection  with  the  use  or
	performance of this software.

	****************************************************************
)%
MODULE 
    Hostnm(
	LANGUAGE (BLISS32),
	ADDRESSING_MODE(EXTERNAL=LONG_RELATIVE,
			NONEXTERNAL=LONG_RELATIVE),
	LIST (ASSEMBLY, BINARY, NOEXPAND)) =

BEGIN

!++
! HOSTNM.BLI
!
! Program to test host name/address TCP interface.
!
!--

LIBRARY 'SYS$LIBRARY:STARLET';
LIBRARY 'CMUIP_SRC:[central]NETWORK';
LIBRARY 'CMUIP_SRC:[central]NETCOMMON';
LIBRARY 'CMUIP_SRC:[central]NETERROR';
LIBRARY 'IPNCP';


%SBTTL 'GTHST routines'

ROUTINE Name_2_Addr (Name_Desc_A) =
    BEGIN
    BIND
	Name_Desc	= .Name_Desc_A		: $BBLOCK;
    EXTERNAL ROUTINE
	STR$CONCAT	: BLISS ADDRESSING_MODE (GENERAL),
	STR$FREE1_DX	: BLISS ADDRESSING_MODE (GENERAL);
    LOCAL
	Nam_Look	: GTHST_NMLOOK_BLOCK;
    LOCAL
	Temp_Desc	: $BBLOCK [DSC$K_S_BLN],
	NETIOSB		: NetIO_Status_Block,
	NetChan		: WORD UNSIGNED,
	Status;

    $Init_DynDesc (Temp_Desc);

    Status = STR$CONCAT (Temp_Desc, Name_Desc,
		$DESCRIPTOR (%STRING(%CHAR(0))));

    Status = $ASSIGN (DEVNAM = %ASCID 'INET$DEVICE', CHAN = NetChan);
    IF NOT .Status THEN Signal_Stop (.Status);

    Status = NET$GTHST (
		BUFADRS		= Nam_Look,
		BUFSIZE		= %ALLOCATION (Nam_Look),
		GTHFUNCT	= GTH_NAMADR,
		GTHP1		= .Temp_Desc [DSC$A_POINTER],
		IOCHAN		= .NetChan,
		IO$SB		= NETIOSB);

    $DASSGN (CHAN = .NetChan);

    IF NOT .Status THEN Signal_Stop (.Status);
    Status = .NetIOSB [NSB$Status];
    IF NOT .Status
	THEN BEGIN
	IF .Status EQL SS$_ABORT
	    THEN RETURN Signal (.NetIOSB [NSB$XStatus], 0)
	    ELSE RETURN Signal (.Status);
	END;

    Status = STR$FREE1_DX (Temp_Desc);
    IF NOT .Status THEN RETURN Signal (.Status);

    INCR I FROM 0 TO .Nam_Look[GH$NL_ADRCNT] - 1 DO
	BEGIN
	BIND
	    Addr_List	= Nam_Look [GH$NL_ADRLST]	: VECTOR [,LONG],
	    This_Addr	= Addr_List [.I]		: VECTOR [,BYTE];

	PrintTT('  Address [!UL] = !UB.!UB.!UB.!UB!/',
		.I + 1,
		.This_Addr [0],
		.This_Addr [1],
		.This_Addr [2],
		.This_Addr [3]);
	END;

    SS$_NORMAL
    END;


%SBTTL 'DO_HOST - main routine to handle host name/address string'

GLOBAL ROUTINE Do_HostNm (Host_Desc_A) =
    BEGIN
    BIND
	Host_Desc	= .Host_Desc_A : $BBLOCK;
    EXTERNAL ROUTINE
	STR$FREE1_DX	: BLISS ADDRESSING_MODE (GENERAL),
	Parse_IP_Address,
	ADDR_2_Name,
	Host_Full_Name;
    LOCAL
	InAddr,
	Full_Name	: $BBLOCK [DSC$K_S_BLN] PRESET (
			[DSC$B_DTYPE]	= DSC$K_DTYPE_T,
			[DSC$B_CLASS]	= DSC$K_CLASS_D),
	STATUS;

    Status = Parse_IP_Address (Host_Desc, InAddr);
    IF .Status
	THEN Status = Addr_2_Name (.InAddr, Full_Name)
	ELSE Status = Host_Full_Name (Host_Desc, Full_Name);
    IF NOT .Status THEN RETURN Signal (.Status);

    PrintTT('Host ''!AS'' Full Name = ''!AS''!/', Host_Desc, Full_Name);

    Status = Name_2_Addr (Full_Name);
    IF NOT .Status THEN RETURN Signal (.Status);

    Status = STR$FREE1_DX (Full_Name);
    IF NOT .Status THEN RETURN Signal (.Status);

    PrintTT('!/');

    SS$_NORMAL
    END;

END
ELUDOM